FileMgr

✏️ /usr/share/vim/vim91/indent/dtd.vim

✕ Tutup

" Vim indent file
" Language:		DTD (Document Type Definition for XML)
" Maintainer:		Doug Kearns <dougkearns@gmail.com>
" Previous Maintainer:	Nikolai Weibull <now@bitwi.se>
" Last Change:		24 Sep 2021

" Only load this indent file when no other was loaded.
if exists("b:did_indent")
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetDTDIndent()
setlocal indentkeys=!^F,o,O,>
setlocal nosmartindent

let b:undo_indent = "setl inde< indk< si<"

if exists("*GetDTDIndent")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

" TODO: Needs to be adjusted to stop at [, <, and ].
let s:token_pattern = '^[^[:space:]]\+'

function s:lex1(input, start, ...)
  let pattern = a:0 > 0 ? a:1 : s:token_pattern
  let start = matchend(a:input, '^\_s*', a:start)
  if start == -1
    return ["", a:start]
  endif
  let end = matchend(a:input, pattern, start)
  if end == -1
    return ["", a:start]
  endif
  let token = strpart(a:input, start, end - start)
  return [token, end]
endfunction

function s:lex(input, start, ...)
  let pattern = a:0 > 0 ? a:1 : s:token_pattern
  let info = s:lex1(a:input, a:start, pattern)
  while info[0] == '--'
    let info = s:lex1(a:input, info[1], pattern)
    while info[0] != "" && info[0] != '--'
      let info = s:lex1(a:input, info[1], pattern)
    endwhile
    if info[0] == ""
      return info
    endif
    let info = s:lex1(a:input, info[1], pattern)
  endwhile
  return info
endfunction

function s:indent_to_innermost_parentheses(line, end)
  let token = '('
  let end = a:end
  let parentheses = [end - 1]
  while token != ""
    let [token, end] = s:lex(a:line, end, '^\%([(),|]\|[A-Za-z0-9_-]\+\|#P\=CDATA\|%[A-Za-z0-9_-]\+;\)[?*+]\=')
    if token[0] == '('
      call add(parentheses, end - 1)
    elseif token[0] == ')'
      if len(parentheses) == 1
        return [-1, end]
      endif
      call remove(parentheses, -1)
    endif
  endwhile
  return [parentheses[-1] - strridx(a:line, "\n", parentheses[-1]), end]
endfunction

" TODO: Line and end could be script global (think OO members).
function GetDTDIndent()
  if v:lnum == 1
    return 0
  endif
  
  " Begin by searching back for a <! that isn’t inside a comment.
  " From here, depending on what follows immediately after, parse to
  " where we’re at to determine what to do.
  if search('<!', 'bceW') == 0
    return indent(v:lnum - 1)
  endif
  let lnum = line('.')
  let col = col('.')
  let indent = indent('.')
  let line = lnum == v:lnum ? getline(lnum) : join(getline(lnum, v:lnum - 1), "\n")

let [declaration, end] = s:lex1(line, col)
  if declaration == ""
    return indent + shiftwidth()
  elseif declaration == '--'
    " We’re looking at a comment.  Now, simply determine if the comment is
    " terminated or not.  If it isn’t, let Vim take care of that using
    " 'comments' and 'autoindent'. Otherwise, indent to the first lines level.
    while declaration != ""
      let [declaration, end] = s:lex(line, end)
      if declaration == "-->"
        return indent
      endif
    endwhile
    return -1
  elseif declaration == 'ELEMENT'
    " Check for element name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Check for token following element name.  This can be a specification of
    " whether the start or end tag may be omitted.  If nothing is found, indent
    " one level.
    let [token, end] = s:lex(line, end, '^\%([-O(]\|ANY\|EMPTY\)')
    let n = 0
    while token =~ '[-O]' && n < 2
      let [token, end] = s:lex(line, end, '^\%([-O(]\|ANY\|EMPTY\)')
      let n += 1
    endwhile
    if token == ""
      return indent + shiftwidth()
    endif

" Next comes the content model.  If the token we’ve found isn’t a
    " parenthesis it must be either ANY, EMPTY or some random junk.  Either
    " way, we’re done indenting this element, so set it to that of the first
    " line so that the terminating “>” winds up having the same indentation.
    if token != '('
      return indent
    endif

" Now go through the content model.  We need to keep track of the nesting
    " of parentheses.  As soon as we hit 0 we’re done.  If that happens we must
    " have a complete content model.  Thus set indentation to be the same as that
    " of the first line so that the terminating “>” winds up having the same
    " indentation.  Otherwise, we’ll indent to the innermost parentheses not yet
    " matched.
    let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
    if indent_of_innermost != -1
      return indent_of_innermost
    endif

" Finally, look for any additions and/or exceptions to the content model.
    " This is defined by a “+” or “-” followed by another content model
    " declaration.
    " TODO: Can the “-” be separated by whitespace from the “(”?
    let seen = { '+(': 0, '-(': 0 }
    while 1
      let [additions_exceptions, end] = s:lex(line, end, '^[+-](')
      if additions_exceptions != '+(' && additions_exceptions != '-('
        let [token, end] = s:lex(line, end)
        if token == '>'
          return indent
        endif
        " TODO: Should use s:lex here on getline(v:lnum) and check for >.
        return getline(v:lnum) =~ '^\s*>' || count(values(seen), 0) == 0 ? indent : (indent + shiftwidth())
      endif

" If we’ve seen an addition or exception already and this is of the same
      " kind, the user is writing a broken DTD.  Time to bail.
      if seen[additions_exceptions]
        return indent
      endif
      let seen[additions_exceptions] = 1

let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
      if indent_of_innermost != -1
        return indent_of_innermost
      endif
    endwhile
  elseif declaration == 'ATTLIST'
    " Check for element name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Check for any number of attributes.
    while 1
      " Check for attribute name.  If none exists, indent one level, unless the
      " current line is a lone “>”, in which case we indent to the same level
      " as the first line.  Otherwise, if the attribute name is “>”, we have
      " actually hit the end of the attribute list, in which case we indent to
      " the same level as the first line.
      let [name, end] = s:lex(line, end)
      if name == ""
        " TODO: Should use s:lex here on getline(v:lnum) and check for >.
        return getline(v:lnum) =~ '^\s*>' ? indent : (indent + shiftwidth())
      elseif name == ">"
        return indent
      endif

" Check for attribute value declaration.  If none exists, indent two
      " levels.  Otherwise, if it’s an enumerated value, check for nested
      " parentheses and indent to the innermost one if we don’t reach the end
      " of the listc.  Otherwise, just continue with looking for the default
      " attribute value.
      " TODO: Do validation of keywords
      " (CDATA|NMTOKEN|NMTOKENS|ID|IDREF|IDREFS|ENTITY|ENTITIES)?
      let [value, end] = s:lex(line, end, '^\%((\|[^[:space:]]\+\)')
      if value == ""
        return indent + shiftwidth() * 2
      elseif value == 'NOTATION'
        " If this is a enumerated value based on notations, read another token
        " for the actual value.  If it doesn’t exist, indent three levels.
        " TODO: If validating according to above, value must be equal to '('.
        let [value, end] = s:lex(line, end, '^\%((\|[^[:space:]]\+\)')
        if value == ""
          return indent + shiftwidth() * 3
        endif
      endif

if value == '('
        let [indent_of_innermost, end] = s:indent_to_innermost_parentheses(line, end)
        if indent_of_innermost != -1
          return indent_of_innermost
        endif
      endif

" Finally look for the attribute’s default value.  If non exists, indent
      " two levels.
      let [default, end] = s:lex(line, end, '^\%("\_[^"]*"\|#\(REQUIRED\|IMPLIED\|FIXED\)\)')
      if default == ""
        return indent + shiftwidth() * 2
      elseif default == '#FIXED'
        " We need to look for the fixed value.  If non exists, indent three
        " levels.
        let [default, end] = s:lex(line, end, '^"\_[^"]*"')
        if default == ""
          return indent + shiftwidth() * 3
        endif
      endif
    endwhile
  elseif declaration == 'ENTITY'
    " Check for entity name.  If none exists, indent one level.  Otherwise, if
    " the name actually turns out to be a percent sign, “%”, this is a
    " parameter entity.  Read another token to determine the entity name and,
    " again, if none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    elseif name == '%'
      let [name, end] = s:lex(line, end)
      if name == ""
        return indent + shiftwidth()
      endif
    endif

" Now check for the entity value.  If none exists, indent one level.  If it
    " does exist, indent to same level as first line, as we’re now done with
    " this entity.
    "
    " The entity value can be a string in single or double quotes (no escapes
    " to worry about, as entities are used instead).  However, it can also be
    " that this is an external unparsed entity.  In that case we have to look
    " further for (possibly) a public ID and an URI followed by the NDATA
    " keyword and the actual notation name.  For the public ID and URI, indent
    " two levels, if they don’t exist.  If the NDATA keyword doesn’t exist,
    " indent one level.  Otherwise, if the actual notation name doesn’t exist,
    " indent two level.  If it does, indent to same level as first line, as
    " we’re now done with this entity.
    let [value, end] = s:lex(line, end)
    if value == ""
      return indent + shiftwidth()
    elseif value == 'SYSTEM' || value == 'PUBLIC'
      let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
      if quoted_string == ""
        return indent + shiftwidth() * 2
      endif

if value == 'PUBLIC'
        let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
        if quoted_string == ""
          return indent + shiftwidth() * 2
        endif
      endif

let [ndata, end] = s:lex(line, end)
      if ndata == ""
        return indent + shiftwidth()
      endif

let [name, end] = s:lex(line, end)
      return name == "" ? (indent + shiftwidth() * 2) : indent
    else
      return indent
    endif
  elseif declaration == 'NOTATION'
    " Check for notation name.  If none exists, indent one level.
    let [name, end] = s:lex(line, end)
    if name == ""
      return indent + shiftwidth()
    endif

" Now check for the external ID.  If none exists, indent one level.
    let [id, end] = s:lex(line, end)
    if id == ""
      return indent + shiftwidth()
    elseif id == 'SYSTEM' || id == 'PUBLIC'
      let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\)')
      if quoted_string == ""
        return indent + shiftwidth() * 2
      endif

if id == 'PUBLIC'
        let [quoted_string, end] = s:lex(line, end, '\%("[^"]\+"\|''[^'']\+''\|>\)')
        if quoted_string == ""
          " TODO: Should use s:lex here on getline(v:lnum) and check for >.
          return getline(v:lnum) =~ '^\s*>' ? indent : (indent + shiftwidth() * 2)
        elseif quoted_string == '>'
          return indent
        endif
      endif
    endif

return indent
  endif

" TODO: Processing directives could be indented I suppose.  But perhaps it’s
  " just as well to let the user decide how to indent them (perhaps extending
  " this function to include proper support for whatever processing directive
  " language they want to use).

" Conditional sections are simply passed along to let Vim decide what to do
  " (and hence the user).
  return -1
endfunction

let &cpo = s:cpo_save
unlet s:cpo_save

Batal

⬅ vim91 160 item

Nama	Tipe	Ukuran	Diubah	Perm	Aksi
📄 aap.vim	vim	331 B	13/07/26 17:17	0644	✏️ ⬇
📄 ada.vim	vim	11.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ant.vim	vim	290 B	13/07/26 17:17	0644	✏️ ⬇
📄 automake.vim	vim	243 B	13/07/26 17:17	0644	✏️ ⬇
📄 awk.vim	vim	7.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 bash.vim	vim	390 B	13/07/26 17:17	0644	✏️ ⬇
📄 basic.vim	vim	250 B	13/07/26 17:17	0644	✏️ ⬇
📄 bib.vim	vim	346 B	13/07/26 17:17	0644	✏️ ⬇
📄 bitbake.vim	vim	583 B	13/07/26 17:17	0644	✏️ ⬇
📄 bst.vim	vim	1.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 bzl.vim	vim	2.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 c.vim	vim	391 B	13/07/26 17:17	0644	✏️ ⬇
📄 cdl.vim	vim	4.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ch.vim	vim	556 B	13/07/26 17:17	0644	✏️ ⬇
📄 chaiscript.vim	vim	1.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 changelog.vim	vim	264 B	13/07/26 17:17	0644	✏️ ⬇
📄 chatito.vim	vim	731 B	13/07/26 17:17	0644	✏️ ⬇
📄 clojure.vim	vim	11.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 cmake.vim	vim	3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 cobol.vim	vim	8.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 config.vim	vim	2.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 context.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 cpp.vim	vim	395 B	13/07/26 17:17	0644	✏️ ⬇
📄 cs.vim	vim	1.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 css.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 cucumber.vim	vim	2.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 cuda.vim	vim	371 B	13/07/26 17:17	0644	✏️ ⬇
📄 d.vim	vim	605 B	13/07/26 17:17	0644	✏️ ⬇
📄 dictconf.vim	vim	411 B	13/07/26 17:17	0644	✏️ ⬇
📄 dictdconf.vim	vim	414 B	13/07/26 17:17	0644	✏️ ⬇
📄 docbk.vim	vim	336 B	13/07/26 17:17	0644	✏️ ⬇
📄 dosbatch.vim	vim	1.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 dtd.vim	vim	11.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 dtrace.vim	vim	451 B	13/07/26 17:17	0644	✏️ ⬇
📄 dts.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 dune.vim	vim	430 B	13/07/26 17:17	0644	✏️ ⬇
📄 dylan.vim	vim	2.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 eiffel.vim	vim	3.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 elm.vim	vim	3.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 erlang.vim	vim	50.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 eruby.vim	vim	2.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 eterm.vim	vim	743 B	13/07/26 17:17	0644	✏️ ⬇
📄 expect.vim	vim	207 B	13/07/26 17:17	0644	✏️ ⬇
📄 falcon.vim	vim	13.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 fennel.vim	vim	273 B	13/07/26 17:17	0644	✏️ ⬇
📄 fish.vim	vim	2.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 fortran.vim	vim	7.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 framescript.vim	vim	891 B	13/07/26 17:17	0644	✏️ ⬇
📄 freebasic.vim	vim	237 B	13/07/26 17:17	0644	✏️ ⬇
📄 gdscript.vim	vim	4.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 gitconfig.vim	vim	841 B	13/07/26 17:17	0644	✏️ ⬇
📄 gitolite.vim	vim	1.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 go.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 gyp.vim	vim	169 B	13/07/26 17:17	0644	✏️ ⬇
📄 haml.vim	vim	2.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 hamster.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 hare.vim	vim	4.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 hog.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 html.vim	vim	33.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 htmldjango.vim	vim	273 B	13/07/26 17:17	0644	✏️ ⬇
📄 idlang.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ishd.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 j.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 java.vim	vim	4.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 javascript.vim	vim	15.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 javascriptreact.vim	vim	109 B	13/07/26 17:17	0644	✏️ ⬇
📄 json.vim	vim	4.5 KB	13/07/26 17:17	0644	✏️ ⬇
📄 jsonc.vim	vim	4.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 jsp.vim	vim	462 B	13/07/26 17:17	0644	✏️ ⬇
📄 julia.vim	vim	15.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 kotlin.vim	vim	1.5 KB	13/07/26 17:17	0644	✏️ ⬇
📄 krl.vim	vim	4.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ld.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 less.vim	vim	243 B	13/07/26 17:17	0644	✏️ ⬇
📄 lifelines.vim	vim	638 B	13/07/26 17:17	0644	✏️ ⬇
📄 liquid.vim	vim	2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 lisp.vim	vim	349 B	13/07/26 17:17	0644	✏️ ⬇
📄 livebook.vim	vim	206 B	13/07/26 17:17	0644	✏️ ⬇
📄 logtalk.vim	vim	1.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 lua.vim	vim	2.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 luau.vim	vim	252 B	13/07/26 17:17	0644	✏️ ⬇
📄 mail.vim	vim	385 B	13/07/26 17:17	0644	✏️ ⬇
📄 make.vim	vim	3.5 KB	13/07/26 17:17	0644	✏️ ⬇
📄 matlab.vim	vim	4.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 meson.vim	vim	5.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 mf.vim	vim	164 B	13/07/26 17:17	0644	✏️ ⬇
📄 mma.vim	vim	2.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 mp.vim	vim	9.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 nginx.vim	vim	1.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 nsis.vim	vim	3.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 objc.vim	vim	1.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 obse.vim	vim	1.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ocaml.vim	vim	9.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 occam.vim	vim	4.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 pascal.vim	vim	5.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 perl.vim	vim	5.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 php.vim	vim	25.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 postscr.vim	vim	1.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 pov.vim	vim	2.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 prolog.vim	vim	1.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ps1.vim	vim	410 B	13/07/26 17:17	0644	✏️ ⬇
📄 pyrex.vim	vim	326 B	13/07/26 17:17	0644	✏️ ⬇
📄 python.vim	vim	886 B	13/07/26 17:17	0644	✏️ ⬇
📄 qb64.vim	vim	232 B	13/07/26 17:17	0644	✏️ ⬇
📄 qml.vim	vim	1.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 quarto.vim	vim	23 B	13/07/26 17:17	0644	✏️ ⬇
📄 r.vim	vim	14 KB	13/07/26 17:17	0644	✏️ ⬇
📄 racket.vim	vim	2.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 raku.vim	vim	3.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 raml.vim	vim	285 B	13/07/26 17:17	0644	✏️ ⬇
📄 rapid.vim	vim	8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 readline.vim	vim	786 B	13/07/26 17:17	0644	✏️ ⬇
📄 rhelp.vim	vim	2.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rmd.vim	vim	2.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rnoweb.vim	vim	1.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rpl.vim	vim	1.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rrst.vim	vim	1.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rst.vim	vim	1.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 ruby.vim	vim	30.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 rust.vim	vim	10.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sas.vim	vim	5.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sass.vim	vim	926 B	13/07/26 17:17	0644	✏️ ⬇
📄 scala.vim	vim	19.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 scheme.vim	vim	372 B	13/07/26 17:17	0644	✏️ ⬇
📄 scss.vim	vim	191 B	13/07/26 17:17	0644	✏️ ⬇
📄 sdl.vim	vim	2.8 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sh.vim	vim	9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sml.vim	vim	6.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 solidity.vim	vim	12.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sql.vim	vim	1.2 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sqlanywhere.vim	vim	13 KB	13/07/26 17:17	0644	✏️ ⬇
📄 sshconfig.vim	vim	796 B	13/07/26 17:17	0644	✏️ ⬇
📄 systemverilog.vim	vim	10.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 tcl.vim	vim	2.5 KB	13/07/26 17:17	0644	✏️ ⬇
📄 tcsh.vim	vim	1.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 teraterm.vim	vim	1.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 tex.vim	vim	13.5 KB	13/07/26 17:17	0644	✏️ ⬇
📄 tf.vim	vim	1.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 tilde.vim	vim	1.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 treetop.vim	vim	785 B	13/07/26 17:17	0644	✏️ ⬇
📄 typescript.vim	vim	14.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 typescriptreact.vim	vim	109 B	13/07/26 17:17	0644	✏️ ⬇
📄 vb.vim	vim	4.7 KB	13/07/26 17:17	0644	✏️ ⬇
📄 verilog.vim	vim	8.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 vhdl.vim	vim	14.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 vim.vim	vim	675 B	13/07/26 17:17	0644	✏️ ⬇
📄 vroom.vim	vim	379 B	13/07/26 17:17	0644	✏️ ⬇
📄 vue.vim	vim	385 B	13/07/26 17:17	0644	✏️ ⬇
📄 wat.vim	vim	458 B	13/07/26 17:17	0644	✏️ ⬇
📄 xf86conf.vim	vim	786 B	13/07/26 17:17	0644	✏️ ⬇
📄 xhtml.vim	vim	325 B	13/07/26 17:17	0644	✏️ ⬇
📄 xinetd.vim	vim	1.3 KB	13/07/26 17:17	0644	✏️ ⬇
📄 xml.vim	vim	7.6 KB	13/07/26 17:17	0644	✏️ ⬇
📄 xsd.vim	vim	253 B	13/07/26 17:17	0644	✏️ ⬇
📄 xslt.vim	vim	297 B	13/07/26 17:17	0644	✏️ ⬇
📄 yacc.vim	vim	858 B	13/07/26 17:17	0644	✏️ ⬇
📄 yaml.vim	vim	5.4 KB	13/07/26 17:17	0644	✏️ ⬇
📄 zig.vim	vim	2.1 KB	13/07/26 17:17	0644	✏️ ⬇
📄 zimbu.vim	vim	3.9 KB	13/07/26 17:17	0644	✏️ ⬇
📄 zsh.vim	vim	411 B	13/07/26 17:17	0644	✏️ ⬇

✏️ Rename

🔑 Ubah Permission